configure.ac 18.5 KB
Newer Older
1
# This file is part of SWIFT.
2
# Copyright (C) 2012 pedro.gonnet@durham.ac.uk.
3
#               2016 p.w.draper@durham.ac.uk.
4
#
Pedro Gonnet's avatar
Pedro Gonnet committed
5
6
7
8
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
9
#
Pedro Gonnet's avatar
Pedro Gonnet committed
10
11
12
13
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
14
#
Pedro Gonnet's avatar
Pedro Gonnet committed
15
16
17
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

18
# Init the project.
19
AC_INIT([SWIFT],[0.4.0])
20
AC_CONFIG_SRCDIR([src/space.c])
21
AC_CONFIG_AUX_DIR([.])
22
AM_INIT_AUTOMAKE
Pedro Gonnet's avatar
Pedro Gonnet committed
23

24
# Add local macro collection.
Pedro Gonnet's avatar
Pedro Gonnet committed
25
26
AC_CONFIG_MACRO_DIR([m4])

27
28
29
30
# Stop default CFLAGS from anyone except the environment.
: ${CFLAGS=""}

# Generate header file.
Pedro Gonnet's avatar
Pedro Gonnet committed
31
32
AM_CONFIG_HEADER(config.h)

33
34
# Find and test the compiler.
AX_CHECK_ENABLE_DEBUG
Peter W. Draper's avatar
Peter W. Draper committed
35
AC_PROG_CC
36
37
AM_PROG_CC_C_O

38
39
40
# Enable POSIX and platform extension preprocessor macros.
AC_USE_SYSTEM_EXTENSIONS

41
42
43
44
# Check for compiler version and vendor.
AX_COMPILER_VENDOR
AX_COMPILER_VERSION

45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
# Interprocedural optimization support. Needs special handling for linking and
# archiving as well as compilation with Intels, needs to be done before
# libtool is configured (to use correct LD).
AC_ARG_ENABLE([ipo],
   [AS_HELP_STRING([--enable-ipo],
     [Enable interprocedural optimization @<:@no/yes@:>@]
   )],
   [enable_ipo="$enableval"],
   [enable_ipo="no"]
)

if test "$enable_ipo" = "yes"; then
   if test "$ax_cv_c_compiler_vendor" = "intel"; then
      CFLAGS="$CFLAGS -ip -ipo"
      LDFLAGS="$LDFLAGS -ipo"
      : ${AR="xiar"}
      : ${LD="xild"}
      AC_MSG_RESULT([added Intel interprocedural optimization support])
   elif test "$ax_cv_c_compiler_vendor" = "gnu"; then
      CFLAGS="$CFLAGS -flto"
      LDFLAGS="$LDFLAGS -flto"
      AC_MSG_RESULT([added GCC interprocedural optimization support])
   elif test "$ax_cv_c_compiler_vendor" = "clang"; then
      CFLAGS="$CFLAGS -emit-llvm"
      AC_MSG_RESULT([added LLVM interprocedural optimization support])
   else
      AC_MSG_WARN([Compiler does not support interprocedural optimization])
   fi
fi

75
76
# Check for MPI. Need to do this before characterising the compiler (C99 mode),
# as this changes the compiler.
77
78
79
80
# We should consider using AX_PROG_CC_MPI to replace AC_PROG_CC when compiling
# whole applications. There are issues with mixing compilers when using this
# macro. See
# http://lists.gnu.org/archive/html/autoconf-archive-maintainers/2011-05/msg00004.html.
81
AC_ARG_ENABLE([mpi],
82
    [AS_HELP_STRING([--enable-mpi],
83
      [Compile with functionality for distributed-memory parallelism using MPI @<:@yes/no@:>@]
84
85
86
87
    )],
    [enable_mpi="$enableval"],
    [enable_mpi="yes"]
)
88
good_mpi="yes"
89
90
if test "$enable_mpi" = "yes"; then
    AX_MPI([CC="$MPICC" AC_DEFINE(HAVE_MPI, 1, [Define if you have the MPI library.]) ])
91
    MPI_LIBRARY="Unknown MPI"
92
93
94

    # Various MPI implementations require additional libraries when also using
    # threads. Use mpirun (on PATH) as that seems to be only command with
95
96
97
98
99
100
    # version flag, allow MPIRUN to override for systems that insist on
    # a non-standard name (PRACE).
    : ${MPIRUN='mpirun'}
    if test "$MPIRUN" = "mpirun"; then
       AC_PATH_PROG([MPIRUN],[mpirun],[notfound])
    fi
101
102
    if test "$MPIRUN" = "notfound"; then
       AC_MSG_WARN([Cannot find mpirun command on PATH, thread support may not be correct])
103
       enable_mpi="no"
104
105
106
107
108
109
110
111
112
113
114
    else
       # Special options we know about.
       # Intel: -mt_mpi
       # PLATFORM: -lmtmpi
       # OpenMPI: nothing, but library should be built correctly.
       # Set MPI_THREAD_LIBS and add to linker commands as necessary.
       AC_MSG_CHECKING([MPI threads options])
       version=`$MPIRUN -version 2>&1`
       case "$version" in
         *Intel*MPI*)
            MPI_THREAD_LIBS="-mt_mpi"
115
            MPI_LIBRARY="Intel MPI"
116
117
118
119
            AC_MSG_RESULT([Intel MPI])
         ;;
         *Platform*)
            MPI_THREAD_LIBS="-lmtmpi"
120
            MPI_LIBRARY="PLATFORM MPI"
121
122
123
124
            AC_MSG_RESULT([PLATFORM MPI])
         ;;
         *"Open MPI"*)
            MPI_THREAD_LIBS=""
125
            MPI_LIBRARY="Open MPI"
126
            AC_MSG_RESULT([Open MPI])
127
128
129
130
131
132
133
134
135
            #  OpenMPI should be 1.8.6 or later, if not complain.
            #  Version is last word on first line of -version output.
            revision=`mpirun -version 2>&1 | grep "Open MPI" | awk '{print $NF}'`
            AX_COMPARE_VERSION( $revision, [ge], [1.8.6],,[good_mpi="no"] )
            if test "$good_mpi" = "no"; then
                AC_MSG_WARN([
    Open MPI version should be at least 1.8.6 (is $revision)])
                enable_mpi="yes (but with warning)"
            fi
136
137
138
139
140
141
142
143
         ;;
         *)
            MPI_THREAD_LIBS=""
            AC_MSG_RESULT([unknown])
         ;;
       esac
       AC_SUBST([MPI_THREAD_LIBS])
    fi
144
    AC_DEFINE_UNQUOTED([SWIFT_MPI_LIBRARY], ["$MPI_LIBRARY"], [The MPI library name, if known.])
145
fi
146
AM_CONDITIONAL([HAVEMPI],[test $enable_mpi = "yes"])
147

148
149
150
# Indicate that MPIRUN can be modified by an environement variable
AC_ARG_VAR(MPIRUN, Path to the mpirun command if non-standard)

151
152
153
# Add libtool support (now that CC is defined).
LT_INIT

154
# Need C99 and inline support.
Pedro Gonnet's avatar
Pedro Gonnet committed
155
AC_PROG_CC_C99
Peter W. Draper's avatar
Peter W. Draper committed
156
157
AC_C_INLINE

158
159
160
161
# If debugging try to show inlined functions.
if test "x$enable_debug" = "xyes"; then
   #  Show inlined functions.
   if test "$ax_cv_c_compiler_vendor" = "gnu"; then
162
163
164
165
166
167
      # Would like to use -gdwarf and let the compiler pick a good version
      # but that doesn't always work.
      AX_CHECK_COMPILE_FLAG([-gdwarf -fvar-tracking-assignments],
        [inline_EXTRA_FLAGS="-gdwarf -fvar-tracking-assignments"],
        [inline_EXTRA_FLAGS="-gdwarf-2 -fvar-tracking-assignments"])
      CFLAGS="$CFLAGS $inline_EXTRA_FLAGS"
168
169
170
171
172
   elif test "$ax_cv_c_compiler_vendor" = "intel"; then
      CFLAGS="$CFLAGS -debug inline-debug-info"
   fi
fi

173
174
175
176
177
178
179
180
181
182
183
184
# Check if task debugging is on.
AC_ARG_ENABLE([task-debugging],
   [AS_HELP_STRING([--enable-task-debugging],
     [Store task timing information and generate task dump files @<:@yes/no@:>@]
   )],
   [enable_task_debugging="$enableval"],
   [enable_task_debugging="no"]
)
if test "$enable_task_debugging" = "yes"; then
   AC_DEFINE([SWIFT_DEBUG_TASKS],1,[Enable task debugging])
fi

185
# Define HAVE_POSIX_MEMALIGN if it works.
Pedro Gonnet's avatar
Pedro Gonnet committed
186
187
AX_FUNC_POSIX_MEMALIGN

188
189
# Only optimize if allowed, otherwise assume user will set CFLAGS as
# appropriate.
190
AC_ARG_ENABLE([optimization],
191
   [AS_HELP_STRING([--enable-optimization],
192
     [Enable compile time optimization flags for host @<:@yes/no@:>@]
193
194
195
   )],
   [enable_opt="$enableval"],
   [enable_opt="yes"]
196
197
)

198
199
200
201
202
203
204
205
206
207
208
209
210
211
#  Disable vectorisation for known compilers. This switches off optimizations
#  that could be enabled above, so in general should be appended. Slightly odd
#  implementation as want to describe as --disable-vec, but macro is enable
#  (there is no enable action).
AC_ARG_ENABLE([vec],
   [AS_HELP_STRING([--disable-vec],
     [Disable vectorization]
   )],
   [enable_vec="$enableval"],
   [enable_vec="yes"]
)

HAVEVECTORIZATION=0

212
if test "$enable_opt" = "yes" ; then
213
214
215
216
217
218
219
220
221

   # Add code optimisation flags and tuning to host. This is a funny macro
   # that does not like CFLAGS being already set. Work around that as we have
   # at least set it to "", so it is set.
   ac_test_CFLAGS="no"
   old_CFLAGS="$CFLAGS"
   AX_CC_MAXOPT
   ac_test_CFLAGS="yes"
   CFLAGS="$old_CFLAGS $CFLAGS"
222
223
224
225
226
227
228
229
230
231

   # Check SSE & AVX support (some overlap with AX_CC_MAXOPT).
   # Don't use the SIMD_FLAGS result with Intel compilers. The -x<code>
   # value from AX_CC_MAXOPT should be sufficient.
   AX_EXT
   if test "$SIMD_FLAGS" != ""; then
       if test "$ax_cv_c_compiler_vendor" != "intel"; then
           CFLAGS="$CFLAGS $SIMD_FLAGS"
       fi
   fi
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250


   if test "$enable_vec" = "no"; then
      if test "$ax_cv_c_compiler_vendor" = "intel"; then
      	 CFLAGS="$CFLAGS -no-vec -no-simd"
      	 AC_MSG_RESULT([disabled Intel vectorization])
      elif test "$ax_cv_c_compiler_vendor" = "gnu"; then
      	 CFLAGS="$CFLAGS -fno-tree-vectorize"
      	 AC_MSG_RESULT([disabled GCC vectorization])
      elif test "$ax_cv_c_compiler_vendor" = "clang"; then
         CFLAGS="$CFLAGS -fno-vectorize -fno-slp-vectorize"
         AC_MSG_RESULT([disabled clang vectorization])
      else
         AC_MSG_WARN([Do not know how to disable vectorization for this compiler])
      fi
   else
      AC_DEFINE([WITH_VECTORIZATION],1,[Enable vectorization])
      HAVEVECTORIZATION=1
   fi
251
fi
252
253
AM_CONDITIONAL([HAVEVECTORIZATION],[test -n "$HAVEVECTORIZATION"])

Peter W. Draper's avatar
Peter W. Draper committed
254

255
# Add address sanitizer options to flags, if requested. Only useful for GCC
256
# version 4.8 and later and clang.
257
AC_ARG_ENABLE([sanitizer],
258
   [AS_HELP_STRING([--enable-sanitizer],
259
     [Enable memory error detection using address sanitizer @<:@no/yes@:>@]
260
261
262
   )],
   [enable_san="$enableval"],
   [enable_san="no"]
263
264
)

265
266
267
268
if test "$enable_san" = "yes"; then
   if test "$ax_cv_c_compiler_vendor" = "gnu"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [4.8.0],
                          [enable_san="yes"], [enable_san="no"] )
269
270
271
272
273
274
   elif test "$ax_cv_c_compiler_vendor" = "clang"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [3.2.0],
                          [enable_san="yes"], [enable_san="no"] )
   fi
   if test "$enable_san" = "yes"; then
      CFLAGS="$CFLAGS -fsanitize=address -fno-omit-frame-pointer"
275
      AC_MSG_RESULT([added address sanitizer support])
276
277
   else
      AC_MSG_WARN([Compiler does not support address sanitizer option])
278
279
280
   fi
fi

281

282
# Autoconf stuff.
Pedro Gonnet's avatar
Pedro Gonnet committed
283
284
285
286
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_HEADER_STDC

287
# Check for the libraries we will need.
Pedro Gonnet's avatar
Pedro Gonnet committed
288
289
AC_CHECK_LIB(m,sqrt,,AC_MSG_ERROR(something is wrong with the math library!))

290
# Check for pthreads.
291
AX_PTHREAD([LIBS="$PTHREAD_LIBS $LIBS" CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
292
    CC="$PTHREAD_CC" LDFLAGS="$LDFLAGS $PTHREAD_LIBS $LIBS"],
Pedro Gonnet's avatar
Pedro Gonnet committed
293
294
295
296
    AC_MSG_ERROR([Could not find a working version of
    the pthread library. Make sure you have the library and header files installed
    or use CPPFLAGS and LDFLAGS if the library is installed in a
    non-standard location.]))
297

298

299
300
301
# Check for metis. Note AX_LIB_METIS exists, but cannot be configured
# to be default off (i.e. given no option it tries to locate METIS), so we
# don't use that.
302
have_metis="no"
303
AC_ARG_WITH([metis],
304
    [AS_HELP_STRING([--with-metis=PATH],
305
       [root directory where metis is installed @<:@yes/no@:>@]
306
307
308
309
310
311
    )],
    [],
    [with_metis="no"]
)
if test "x$with_metis" != "xno"; then
   if test "x$with_metis" != "xyes" -a "x$with_metis" != "x"; then
312
313
      METIS_LIBS="-L$with_metis/lib -lmetis"
      METIS_INCS="-I$with_metis/include"
314
   else
315
      METIS_LIBS="-lmetis"
316
      METIS_INCS=""
317
   fi
318
   have_metis="yes"
319
320
   AC_CHECK_LIB([metis],[METIS_PartGraphKway],
      AC_DEFINE([HAVE_METIS],1,[The metis library appears to be present.]),
321
      AC_MSG_ERROR(something is wrong with the metis library!),$METIS_LIBS)
322
fi
323
AC_SUBST([METIS_LIBS])
324
AC_SUBST([METIS_INCS])
325
AM_CONDITIONAL([HAVEMETIS],[test -n "$METIS_LIBS"])
326

327
328
329
330
331
332
333
334
335
336
337
#  Check for tcmalloc a fast malloc that is part of the gperftools.
have_tcmalloc="no"
AC_ARG_WITH([tcmalloc],
   [AS_HELP_STRING([--with-tcmalloc],
      [use tcmalloc library or specify the directory with lib @<:@yes/no@:>@]
   )],
   [with_tcmalloc="$withval"],
   [with_tcmalloc="no"]
)
if test "x$with_tcmalloc" != "xno"; then
   if test "x$with_tcmalloc" != "xyes" && test "x$with_tcmalloc" != "x"; then
338
      tclibs="-L$with_tcmalloc -ltcmalloc"
339
   else
340
      tclibs="-ltcmalloc"
341
342
   fi
   AC_CHECK_LIB([tcmalloc],[tc_cfree],[have_tcmalloc="yes"],[have_tcmalloc="no"],
343
                $tclibs)
344
345
346
347

   #  Could just have the minimal version.
   if test "$have_tcmalloc" = "no"; then
      if test "x$with_tcmalloc" != "xyes" && test "x$with_tcmalloc" != "x"; then
348
         tclibs="-L$with_tcmalloc -ltcmalloc_minimal"
349
      else
350
         tclibs="-ltcmalloc_minimal"
351
352
      fi
      AC_CHECK_LIB([tcmalloc],[tc_cfree],[have_tcmalloc="yes"],[have_tcmalloc="no"],
353
                   $tclibs)
354
   fi
Pedro Gonnet's avatar
Pedro Gonnet committed
355

356
357
358
359
   if test "$have_tcmalloc" = "yes"; then
      TCMALLOC_LIBS="$tclibs"

      # These are recommended for GCC.
360
      if test "$ax_cv_c_compiler_vendor" = "gnu"; then
361
362
363
364
         CFLAGS="$CFLAGS -fno-builtin-malloc -fno-builtin-calloc -fno-builtin-realloc -fno-builtin-free"
      fi
   else
      TCMALLOC_LIBS=""
365
366
367
368
369
   fi
fi
AC_SUBST([TCMALLOC_LIBS])
AM_CONDITIONAL([HAVETCMALLOC],[test -n "$TCMALLOC_LIBS"])

370
#  Check for -lprofiler usually part of the gperftools along with tcmalloc.
371
372
373
374
375
376
377
378
379
380
have_profiler="no"
AC_ARG_WITH([profiler],
   [AS_HELP_STRING([--with-profiler],
      [use cpu profiler library or specify the directory with lib @<:@yes/no@:>@]
   )],
   [with_profiler="$withval"],
   [with_profiler="yes"]
)
if test "x$with_profiler" != "xno"; then
   if test "x$with_profiler" != "xyes" && test "x$with_profiler" != "x"; then
381
      proflibs="-L$with_profiler -lprofiler"
382
   else
383
      proflibs="-lprofiler"
384
385
   fi
   AC_CHECK_LIB([profiler],[ProfilerFlush],[have_profiler="yes"],[have_profiler="no"],
386
387
388
389
390
391
392
                $proflibs)

   if test "$have_profiler" = "yes"; then
      PROFILER_LIBS="$proflibs"
   else
      PROFILER_LIBS=""
   fi
393
394
395
fi
AC_SUBST([PROFILER_LIBS])
AM_CONDITIONAL([HAVEPROFILER],[test -n "$PROFILER_LIBS"])
Pedro Gonnet's avatar
Pedro Gonnet committed
396

397
# Check for HDF5. This is required.
398
AX_LIB_HDF5
399

400
401
402
403
if test "$with_hdf5" != "yes"; then
    AC_MSG_ERROR([Could not find a working HDF5 library])
fi

404
405
406
407
# We want to know if this HDF5 supports MPI and whether we should use it.
# The default is to use MPI support if it is available, i.e. this is
# a parallel HDF5.
# To do this need to ask the HDF5 compiler about its configuration,
408
# -showconfig should have yes/no.
409
410
have_parallel_hdf5="no"
if test "$with_hdf5" = "yes"; then
411
412
    AC_ARG_ENABLE([parallel-hdf5],
       [AS_HELP_STRING([--enable-parallel-hdf5],
413
         [Enable parallel HDF5 library MPI functions if available. @<:@yes/no@:>@]
414
415
416
417
418
419
420
421
422
423
424
425
426
       )],
       [enable_parallel_hdf5="$enableval"],
       [enable_parallel_hdf5="yes"]
    )

    if test "$enable_parallel_hdf5" = "yes"; then
        AC_MSG_CHECKING([for HDF5 parallel support])
        parallel=`$H5CC -showconfig | grep "Parallel HDF5:" | awk '{print $3}'`
        if test "$parallel" = "yes"; then
            have_parallel_hdf5="yes"
            AC_DEFINE([HAVE_PARALLEL_HDF5],1,[HDF5 library supports parallel access])
        fi
        AC_MSG_RESULT($parallel)
427
428
429
430
    fi
fi
AM_CONDITIONAL([HAVEPARALLELHDF5],[test "$have_parallel_hdf5" = "yes"])

431
# Check for setaffinity.
432
AC_CHECK_FUNC(pthread_setaffinity_np, AC_DEFINE([HAVE_SETAFFINITY],[1],
Pedro Gonnet's avatar
Pedro Gonnet committed
433
    [Defined if pthread_setaffinity_np exists.]) )
434
435
AM_CONDITIONAL(HAVESETAFFINITY,
    [test "$ac_cv_func_pthread_setaffinity_np" = "yes"])
436

437
have_numa="no"
438
439
440
441
442
if test "$ac_cv_func_pthread_setaffinity_np" = "yes"; then
  # Check for libnuma.
  AC_CHECK_HEADER([numa.h])
  if test "$ac_cv_header_numa_h" = "yes"; then
    AC_CHECK_LIB([numa], [numa_available])
443
    have_numa="yes"
444
445
  fi
fi
Angus Lepper's avatar
Angus Lepper committed
446

447
448
449
450
451
452
453
454
455
456
457
# Check for FFTW
have_fftw3="no"
AC_CHECK_HEADER([fftw3.h])
if test "$ac_cv_header_fftw3_h" = "yes"; then
   AC_CHECK_LIB([fftw3],[fftw_malloc], [AC_DEFINE([HAVE_FFTW],
   [1],[Defined if FFTW 3.x exists.])] )
   FFTW_LIBS="-lfftw3"
   have_fftw3="yes"
fi
AC_SUBST([FFTW_LIBS])

458
459
460
# Check for Intel intrinsics header optionally used by vector.h.
AC_CHECK_HEADERS([immintrin.h])

461
# Check for timing functions needed by cycle.h.
Pedro Gonnet's avatar
Pedro Gonnet committed
462
463
AC_HEADER_TIME
AC_CHECK_HEADERS([sys/time.h c_asm.h intrinsics.h mach/mach_time.h])
464
465
466
AC_CHECK_TYPE([hrtime_t],[AC_DEFINE(HAVE_HRTIME_T, 1, [Define to 1 if hrtime_t
is defined in <sys/time.h>])],,
[#if HAVE_SYS_TIME_H
Pedro Gonnet's avatar
Pedro Gonnet committed
467
468
469
470
471
#include <sys/time.h>
#endif])
AC_CHECK_FUNCS([gethrtime read_real_time time_base_to_time clock_gettime mach_absolute_time])
AC_MSG_CHECKING([for _rtc intrinsic])
rtc_ok=yes
472
473
AC_LINK_IFELSE([AC_LANG_PROGRAM(
[[#ifdef HAVE_INTRINSICS_H
Pedro Gonnet's avatar
Pedro Gonnet committed
474
#include <intrinsics.h>
475
#endif]],
476
477
[[_rtc()]])],
[AC_DEFINE(HAVE__RTC,1,[Define if you have the UNICOS _rtc() intrinsic.])],[rtc_ok=no])
Pedro Gonnet's avatar
Pedro Gonnet committed
478
479
AC_MSG_RESULT($rtc_ok)

480
# Add warning flags by default, if these can be used. Option =error adds
481
# -Werror to GCC, clang and Intel.  Note do this last as compiler tests may
482
# become errors, if that's an issue don't use CFLAGS for these, use an AC_SUBST().
483
484
AC_ARG_ENABLE([compiler-warnings],
   [AS_HELP_STRING([--enable-compiler-warnings],
485
     [Enable compile time warning flags, if compiler is known @<:@error/no/yes)@:>@]
486
487
   )],
   [enable_warn="$enableval"],
488
   [enable_warn="error"]
489
490
)
if test "$enable_warn" != "no"; then
491

492
    # AX_CFLAGS_WARN_ALL does not give good warning flags for the Intel compiler
493
    # We will do this by hand instead and only default to the macro for unknown compilers
494
495
    case "$ax_cv_c_compiler_vendor" in
          gnu | clang)
496
             CFLAGS="$CFLAGS -Wall -Wextra -Wno-unused-parameter"
497
          ;;
498
	  intel)
499
             CFLAGS="$CFLAGS -w2 -Wunused-variable"
500
          ;;
501
502
503
	  *)
	     AX_CFLAGS_WARN_ALL
	  ;;
504
    esac
505

506
    # Add a "choke on warning" flag if it exists
507
    if test "$enable_warn" = "error"; then
508
       case "$ax_cv_c_compiler_vendor" in
509
          intel | gnu | clang)
510
511
512
             CFLAGS="$CFLAGS -Werror"
          ;;
       esac
513
    fi
514
515
fi

516
517
518
# Check for git, needed for revision stamps.
AC_PATH_PROG([GIT_CMD], [git])
AC_SUBST([GIT_CMD])
519

520
# Make the documentation. Add conditional to handle disable option.
521
DX_INIT_DOXYGEN(libswift,doc/Doxyfile,doc/)
522
AM_CONDITIONAL([HAVE_DOXYGEN], [test "$ac_cv_path_ac_pt_DX_DOXYGEN" != ""])
Pedro Gonnet's avatar
Pedro Gonnet committed
523

524
# Handle .in files.
525
AC_CONFIG_FILES([Makefile src/Makefile examples/Makefile doc/Makefile doc/Doxyfile tests/Makefile])
526
527
528
529
530
AC_CONFIG_FILES([tests/testReading.sh], [chmod +x tests/testReading.sh])
AC_CONFIG_FILES([tests/testPair.sh], [chmod +x tests/testPair.sh])
AC_CONFIG_FILES([tests/testPairPerturbed.sh], [chmod +x tests/testPairPerturbed.sh])
AC_CONFIG_FILES([tests/test27cells.sh], [chmod +x tests/test27cells.sh])
AC_CONFIG_FILES([tests/test27cellsPerturbed.sh], [chmod +x tests/test27cellsPerturbed.sh])
531
AC_CONFIG_FILES([tests/test125cells.sh], [chmod +x tests/test125cells.sh])
532
AC_CONFIG_FILES([tests/testParser.sh], [chmod +x tests/testParser.sh])
Pedro Gonnet's avatar
Pedro Gonnet committed
533

534
535
# Report general configuration.
AC_MSG_RESULT([
536
537
538
539
540
541
542
   Compiler        : $CC
    - vendor       : $ax_cv_c_compiler_vendor
    - version      : $ax_cv_c_compiler_version
    - flags        : $CFLAGS
   MPI enabled     : $enable_mpi
   HDF5 enabled    : $with_hdf5
    - parallel     : $have_parallel_hdf5
543
   Metis enabled   : $have_metis
544
   FFTW3 enabled   : $have_fftw3
545
   libNUMA enabled : $have_numa
546
547
   Using tcmalloc  : $have_tcmalloc
   CPU profiler    : $have_profiler
548
   Task debugging  : $enable_task_debugging
549
550
])

551
# Generate output.
552
AC_OUTPUT