configure.ac 36.6 KB
Newer Older
1
# This file is part of SWIFT.
2
# Copyright (C) 2012 pedro.gonnet@durham.ac.uk.
3
#               2016 p.w.draper@durham.ac.uk.
4
#
Pedro Gonnet's avatar
Pedro Gonnet committed
5
6
7
8
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
9
#
Pedro Gonnet's avatar
Pedro Gonnet committed
10
11
12
13
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
14
#
Pedro Gonnet's avatar
Pedro Gonnet committed
15
16
17
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

18
# Init the project.
19
AC_INIT([SWIFT],[0.6.0],[https://gitlab.cosma.dur.ac.uk/swift/swiftsim])
20
swift_config_flags="$*"
21
22

#  Need to define this, instead of using fifth argument of AC_INIT, until 2.64.
Matthieu Schaller's avatar
Matthieu Schaller committed
23
AC_DEFINE([PACKAGE_URL],["www.swiftsim.com"], [Package web pages])
24

25
AC_COPYRIGHT
26
AC_CONFIG_SRCDIR([src/space.c])
27
AC_CONFIG_AUX_DIR([.])
lhausamm's avatar
lhausamm committed
28
AM_INIT_AUTOMAKE([subdir-objects])
Pedro Gonnet's avatar
Pedro Gonnet committed
29

30
# Add local macro collection.
Pedro Gonnet's avatar
Pedro Gonnet committed
31
32
AC_CONFIG_MACRO_DIR([m4])

33
34
35
36
# Stop default CFLAGS from anyone except the environment.
: ${CFLAGS=""}

# Generate header file.
Pedro Gonnet's avatar
Pedro Gonnet committed
37
38
AM_CONFIG_HEADER(config.h)

39
40
# Find and test the compiler.
AX_CHECK_ENABLE_DEBUG
Peter W. Draper's avatar
Peter W. Draper committed
41
AC_PROG_CC
42
43
AM_PROG_CC_C_O

44
# If debug is selected then we also define SWIFT_DEVELOP_MODE to control
Peter W. Draper's avatar
Typo    
Peter W. Draper committed
45
# any developer code options.
46
47
48
49
if test "x$ax_enable_debug" != "xno"; then
   AC_DEFINE([SWIFT_DEVELOP_MODE],1,[Enable developer code options])
fi

50
51
52
# Enable POSIX and platform extension preprocessor macros.
AC_USE_SYSTEM_EXTENSIONS

53
54
55
56
# Check for compiler version and vendor.
AX_COMPILER_VENDOR
AX_COMPILER_VERSION

57
58
59
#  Restrict support.
AC_C_RESTRICT

60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
# Interprocedural optimization support. Needs special handling for linking and
# archiving as well as compilation with Intels, needs to be done before
# libtool is configured (to use correct LD).
AC_ARG_ENABLE([ipo],
   [AS_HELP_STRING([--enable-ipo],
     [Enable interprocedural optimization @<:@no/yes@:>@]
   )],
   [enable_ipo="$enableval"],
   [enable_ipo="no"]
)

if test "$enable_ipo" = "yes"; then
   if test "$ax_cv_c_compiler_vendor" = "intel"; then
      CFLAGS="$CFLAGS -ip -ipo"
      LDFLAGS="$LDFLAGS -ipo"
      : ${AR="xiar"}
      : ${LD="xild"}
      AC_MSG_RESULT([added Intel interprocedural optimization support])
   elif test "$ax_cv_c_compiler_vendor" = "gnu"; then
      CFLAGS="$CFLAGS -flto"
      LDFLAGS="$LDFLAGS -flto"
      AC_MSG_RESULT([added GCC interprocedural optimization support])
   elif test "$ax_cv_c_compiler_vendor" = "clang"; then
      CFLAGS="$CFLAGS -emit-llvm"
      AC_MSG_RESULT([added LLVM interprocedural optimization support])
   else
      AC_MSG_WARN([Compiler does not support interprocedural optimization])
   fi
fi

90
91
# Check for MPI. Need to do this before characterising the compiler (C99 mode),
# as this changes the compiler.
92
93
94
95
# We should consider using AX_PROG_CC_MPI to replace AC_PROG_CC when compiling
# whole applications. There are issues with mixing compilers when using this
# macro. See
# http://lists.gnu.org/archive/html/autoconf-archive-maintainers/2011-05/msg00004.html.
96
AC_ARG_ENABLE([mpi],
97
    [AS_HELP_STRING([--enable-mpi],
98
      [Compile with functionality for distributed-memory parallelism using MPI @<:@yes/no@:>@]
99
100
101
102
    )],
    [enable_mpi="$enableval"],
    [enable_mpi="yes"]
)
103
good_mpi="yes"
104
105
if test "$enable_mpi" = "yes"; then
    AX_MPI([CC="$MPICC" AC_DEFINE(HAVE_MPI, 1, [Define if you have the MPI library.]) ])
106
    MPI_LIBRARY="Unknown MPI"
107
108
109

    # Various MPI implementations require additional libraries when also using
    # threads. Use mpirun (on PATH) as that seems to be only command with
110
111
112
113
114
115
    # version flag, allow MPIRUN to override for systems that insist on
    # a non-standard name (PRACE).
    : ${MPIRUN='mpirun'}
    if test "$MPIRUN" = "mpirun"; then
       AC_PATH_PROG([MPIRUN],[mpirun],[notfound])
    fi
116
    if test "$MPIRUN" = "notfound"; then
117
118
       # This may not be fatal (some systems do not allow mpirun on
       # development nodes)., so push on.
119
120
121
122
123
124
125
126
127
128
129
130
       AC_MSG_WARN([Cannot find mpirun command on PATH, thread support may not be correct])
    else
       # Special options we know about.
       # Intel: -mt_mpi
       # PLATFORM: -lmtmpi
       # OpenMPI: nothing, but library should be built correctly.
       # Set MPI_THREAD_LIBS and add to linker commands as necessary.
       AC_MSG_CHECKING([MPI threads options])
       version=`$MPIRUN -version 2>&1`
       case "$version" in
         *Intel*MPI*)
            MPI_THREAD_LIBS="-mt_mpi"
131
            MPI_LIBRARY="Intel MPI"
132
133
134
135
            AC_MSG_RESULT([Intel MPI])
         ;;
         *Platform*)
            MPI_THREAD_LIBS="-lmtmpi"
136
            MPI_LIBRARY="PLATFORM MPI"
137
138
139
140
            AC_MSG_RESULT([PLATFORM MPI])
         ;;
         *"Open MPI"*)
            MPI_THREAD_LIBS=""
141
            MPI_LIBRARY="Open MPI"
142
            AC_MSG_RESULT([Open MPI])
143
144
145
146
147
148
149
150
151
            #  OpenMPI should be 1.8.6 or later, if not complain.
            #  Version is last word on first line of -version output.
            revision=`mpirun -version 2>&1 | grep "Open MPI" | awk '{print $NF}'`
            AX_COMPARE_VERSION( $revision, [ge], [1.8.6],,[good_mpi="no"] )
            if test "$good_mpi" = "no"; then
                AC_MSG_WARN([
    Open MPI version should be at least 1.8.6 (is $revision)])
                enable_mpi="yes (but with warning)"
            fi
152
153
154
155
156
157
158
159
         ;;
         *)
            MPI_THREAD_LIBS=""
            AC_MSG_RESULT([unknown])
         ;;
       esac
       AC_SUBST([MPI_THREAD_LIBS])
    fi
160
    AC_DEFINE_UNQUOTED([SWIFT_MPI_LIBRARY], ["$MPI_LIBRARY"], [The MPI library name, if known.])
161
fi
162
AM_CONDITIONAL([HAVEMPI],[test $enable_mpi = "yes"])
163

Peter W. Draper's avatar
Peter W. Draper committed
164
# Indicate that MPIRUN can be modified by an environment variable
165
166
AC_ARG_VAR(MPIRUN, Path to the mpirun command if non-standard)

167
168
169
# Add libtool support (now that CC is defined).
LT_INIT

170
# Need C99 and inline support.
Pedro Gonnet's avatar
Pedro Gonnet committed
171
AC_PROG_CC_C99
Peter W. Draper's avatar
Peter W. Draper committed
172
173
AC_C_INLINE

174
175
176
177
# If debugging try to show inlined functions.
if test "x$enable_debug" = "xyes"; then
   #  Show inlined functions.
   if test "$ax_cv_c_compiler_vendor" = "gnu"; then
178
179
180
181
182
183
      # Would like to use -gdwarf and let the compiler pick a good version
      # but that doesn't always work.
      AX_CHECK_COMPILE_FLAG([-gdwarf -fvar-tracking-assignments],
        [inline_EXTRA_FLAGS="-gdwarf -fvar-tracking-assignments"],
        [inline_EXTRA_FLAGS="-gdwarf-2 -fvar-tracking-assignments"])
      CFLAGS="$CFLAGS $inline_EXTRA_FLAGS"
184
185
186
187
188
   elif test "$ax_cv_c_compiler_vendor" = "intel"; then
      CFLAGS="$CFLAGS -debug inline-debug-info"
   fi
fi

189
190
191
192
193
194
195
196
197
198
199
200
# Check if task debugging is on.
AC_ARG_ENABLE([task-debugging],
   [AS_HELP_STRING([--enable-task-debugging],
     [Store task timing information and generate task dump files @<:@yes/no@:>@]
   )],
   [enable_task_debugging="$enableval"],
   [enable_task_debugging="no"]
)
if test "$enable_task_debugging" = "yes"; then
   AC_DEFINE([SWIFT_DEBUG_TASKS],1,[Enable task debugging])
fi

201
202
203
204
205
206
207
208
209
210
# Check if threadpool debugging is on.
AC_ARG_ENABLE([threadpool-debugging],
   [AS_HELP_STRING([--enable-threadpool-debugging],
     [Store threadpool mapper timing information and generate threadpool dump files @<:@yes/no@:>@]
   )],
   [enable_threadpool_debugging="$enableval"],
   [enable_threadpool_debugging="no"]
)
if test "$enable_threadpool_debugging" = "yes"; then
   AC_DEFINE([SWIFT_DEBUG_THREADPOOL],1,[Enable threadpool debugging])
211
   LDFLAGS="$LDFLAGS -rdynamic"
212
213
fi

214
215
216
217
218
219
220
221
222
223
224
225
# Check if the general timers are switched on.
AC_ARG_ENABLE([timers],
   [AS_HELP_STRING([--enable-timers],
     [Activate the basic timers @<:@yes/no@:>@]
   )],
   [enable_timers="$enableval"],
   [enable_timers="no"]
)
if test "$enable_timers" = "yes"; then
   AC_DEFINE([SWIFT_USE_TIMERS],1,[Enable individual timers])
fi

226
227
228
229
230
231
232
233
234
235
236
237
# Check if expensive debugging is on.
AC_ARG_ENABLE([debugging-checks],
   [AS_HELP_STRING([--enable-debugging-checks],
     [Activate expensive consistency checks @<:@yes/no@:>@]
   )],
   [enable_debugging_checks="$enableval"],
   [enable_debugging_checks="no"]
)
if test "$enable_debugging_checks" = "yes"; then
   AC_DEFINE([SWIFT_DEBUG_CHECKS],1,[Enable expensive debugging])
fi

238
239
240
241
242
243
244
245
246
247
248
249
# Check whether we want to default to naive cell interactions
AC_ARG_ENABLE([naive-interactions],
   [AS_HELP_STRING([--enable-naive-interactions],
     [Activate use of naive cell interaction functions @<:@yes/no@:>@]
   )],
   [enable_naive_interactions="$enableval"],
   [enable_naive_interactions="no"]
)
if test "$enable_naive_interactions" = "yes"; then
   AC_DEFINE([SWIFT_USE_NAIVE_INTERACTIONS],1,[Enable use of naive cell interaction functions])
fi

250
251
252
253
254
255
256
257
258
259
260
261
262
263
# Check if gravity force checks are on for some particles.
AC_ARG_ENABLE([gravity-force-checks],
   [AS_HELP_STRING([--enable-gravity-force-checks],
     [Activate expensive brute-force gravity checks for a fraction 1/N of all particles @<:@N@:>@]
   )],
   [gravity_force_checks="$enableval"],
   [gravity_force_checks="no"]
)
if test "$gravity_force_checks" == "yes"; then
   AC_MSG_ERROR(Need to specify the fraction of particles to check when using --enable-gravity-force-checks!)
elif test "$gravity_force_checks" != "no"; then
   AC_DEFINE_UNQUOTED([SWIFT_GRAVITY_FORCE_CHECKS], [$enableval] ,[Enable gravity brute-force checks])
fi

264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
# Check if we want to zero the gravity forces for all particles below some ID.
AC_ARG_ENABLE([no-gravity-below-id],
   [AS_HELP_STRING([--enable-no-gravity-below-id],
     [Zeros the gravitational acceleration of all particles with an ID smaller than @<:@N@:>@]
   )],
   [no_gravity_below_id="$enableval"],
   [no_gravity_below_id="no"]
)
if test "$no_gravity_below_id" == "yes"; then
   AC_MSG_ERROR(Need to specify the ID below which particles get zero forces when using --enable-no-gravity-below-id!)
elif test "$no_gravity_below_id" != "no"; then
   AC_DEFINE_UNQUOTED([SWIFT_NO_GRAVITY_BELOW_ID], [$enableval] ,[Particles with smaller ID than this will have zero gravity forces])
fi


279
# Define HAVE_POSIX_MEMALIGN if it works.
Pedro Gonnet's avatar
Pedro Gonnet committed
280
281
AX_FUNC_POSIX_MEMALIGN

282
283
# Only optimize if allowed, otherwise assume user will set CFLAGS as
# appropriate.
284
AC_ARG_ENABLE([optimization],
285
   [AS_HELP_STRING([--enable-optimization],
286
     [Enable compile time optimization flags for host @<:@yes/no@:>@]
287
288
289
   )],
   [enable_opt="$enableval"],
   [enable_opt="yes"]
290
291
)

292
293
294
295
296
297
298
299
300
301
302
303
304
305
#  Disable vectorisation for known compilers. This switches off optimizations
#  that could be enabled above, so in general should be appended. Slightly odd
#  implementation as want to describe as --disable-vec, but macro is enable
#  (there is no enable action).
AC_ARG_ENABLE([vec],
   [AS_HELP_STRING([--disable-vec],
     [Disable vectorization]
   )],
   [enable_vec="$enableval"],
   [enable_vec="yes"]
)

HAVEVECTORIZATION=0

306
if test "$enable_opt" = "yes" ; then
307
308
309
310
311
312
313
314
315

   # Add code optimisation flags and tuning to host. This is a funny macro
   # that does not like CFLAGS being already set. Work around that as we have
   # at least set it to "", so it is set.
   ac_test_CFLAGS="no"
   old_CFLAGS="$CFLAGS"
   AX_CC_MAXOPT
   ac_test_CFLAGS="yes"
   CFLAGS="$old_CFLAGS $CFLAGS"
316
317
318
319
320
321
322
323
324
325

   # Check SSE & AVX support (some overlap with AX_CC_MAXOPT).
   # Don't use the SIMD_FLAGS result with Intel compilers. The -x<code>
   # value from AX_CC_MAXOPT should be sufficient.
   AX_EXT
   if test "$SIMD_FLAGS" != ""; then
       if test "$ax_cv_c_compiler_vendor" != "intel"; then
           CFLAGS="$CFLAGS $SIMD_FLAGS"
       fi
   fi
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344


   if test "$enable_vec" = "no"; then
      if test "$ax_cv_c_compiler_vendor" = "intel"; then
      	 CFLAGS="$CFLAGS -no-vec -no-simd"
      	 AC_MSG_RESULT([disabled Intel vectorization])
      elif test "$ax_cv_c_compiler_vendor" = "gnu"; then
      	 CFLAGS="$CFLAGS -fno-tree-vectorize"
      	 AC_MSG_RESULT([disabled GCC vectorization])
      elif test "$ax_cv_c_compiler_vendor" = "clang"; then
         CFLAGS="$CFLAGS -fno-vectorize -fno-slp-vectorize"
         AC_MSG_RESULT([disabled clang vectorization])
      else
         AC_MSG_WARN([Do not know how to disable vectorization for this compiler])
      fi
   else
      AC_DEFINE([WITH_VECTORIZATION],1,[Enable vectorization])
      HAVEVECTORIZATION=1
   fi
345
fi
346
347
AM_CONDITIONAL([HAVEVECTORIZATION],[test -n "$HAVEVECTORIZATION"])

Peter W. Draper's avatar
Peter W. Draper committed
348

349
# Add address sanitizer options to flags, if requested. Only useful for GCC
350
# version 4.8 and later and clang.
351
AC_ARG_ENABLE([sanitizer],
352
   [AS_HELP_STRING([--enable-sanitizer],
353
     [Enable memory error detection using address sanitizer @<:@no/yes@:>@]
354
355
356
   )],
   [enable_san="$enableval"],
   [enable_san="no"]
357
358
)

359
360
361
362
if test "$enable_san" = "yes"; then
   if test "$ax_cv_c_compiler_vendor" = "gnu"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [4.8.0],
                          [enable_san="yes"], [enable_san="no"] )
363
364
365
366
367
368
   elif test "$ax_cv_c_compiler_vendor" = "clang"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [3.2.0],
                          [enable_san="yes"], [enable_san="no"] )
   fi
   if test "$enable_san" = "yes"; then
      CFLAGS="$CFLAGS -fsanitize=address -fno-omit-frame-pointer"
369
      AC_MSG_RESULT([added address sanitizer support])
370
371
   else
      AC_MSG_WARN([Compiler does not support address sanitizer option])
372
373
374
   fi
fi

375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
# Add the undefined sanitizer option to flags. Only useful for GCC
# version 4.9 and later and clang to detected undefined code behaviour
# such as integer overflow and memory alignment issues.
AC_ARG_ENABLE([undefined-sanitizer],
   [AS_HELP_STRING([--enable-undefined-sanitizer],
     [Enable detection of code that causes undefined behaviour @<:@no/yes@:>@]
   )],
   [enable_ubsan="$enableval"],
   [enable_ubsan="no"]
)

if test "$enable_ubsan" = "yes"; then
   if test "$ax_cv_c_compiler_vendor" = "gnu"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [4.9.0],
                          [enable_ubsan="yes"], [enable_ubsan="no"] )
   elif test "$ax_cv_c_compiler_vendor" = "clang"; then
      AX_COMPARE_VERSION( $ax_cv_c_compiler_version, [ge], [3.7.0],
                          [enable_ubsan="yes"], [enable_ubsan="no"] )
   fi
   if test "$enable_ubsan" = "yes"; then
      CFLAGS="$CFLAGS -fsanitize=undefined"
      AC_MSG_RESULT([added undefined sanitizer support])
   else
      AC_MSG_WARN([Compiler does not support undefined sanitizer option])
   fi
fi

402
# Autoconf stuff.
Pedro Gonnet's avatar
Pedro Gonnet committed
403
404
405
406
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_HEADER_STDC

407
# Check for the libraries we will need.
Pedro Gonnet's avatar
Pedro Gonnet committed
408
409
AC_CHECK_LIB(m,sqrt,,AC_MSG_ERROR(something is wrong with the math library!))

410
# Check for GSL
411
have_gsl="no"
412
AC_CHECK_LIB([gslcblas], [cblas_dgemm])
413
AC_CHECK_LIB([gsl], [gsl_integration_qag])
Peter W. Draper's avatar
Peter W. Draper committed
414
415
416
if test "x$ac_cv_lib_gslcblas_cblas_dgemm" != "x"; then
   have_gsl="yes"
fi
417

418
# Check for pthreads.
419
AX_PTHREAD([LIBS="$PTHREAD_LIBS $LIBS" CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
420
    CC="$PTHREAD_CC" LDFLAGS="$LDFLAGS $PTHREAD_LIBS $LIBS"],
Pedro Gonnet's avatar
Pedro Gonnet committed
421
422
423
424
    AC_MSG_ERROR([Could not find a working version of
    the pthread library. Make sure you have the library and header files installed
    or use CPPFLAGS and LDFLAGS if the library is installed in a
    non-standard location.]))
425

426
# Check whether POSIX thread barriers are implemented (e.g. OSX does not have them)
427
have_pthread_barrier="no"
428
AC_CHECK_LIB(pthread, pthread_barrier_init,
429
	     have_pthread_barrier="yes",
430
	     AC_MSG_WARN(POSIX implementation does not have barriers. SWIFT will use home-made ones.))
431
432
433
if test "x$have_pthread_barrier" == "xyes"; then
  AC_DEFINE([HAVE_PTHREAD_BARRIERS], [1], [The posix library implements barriers])
fi
434

435
436
437
438
# Check whether POSIX file allocation functions exist (e.g. OSX does not have them)
AC_CHECK_LIB(pthread, posix_fallocate,
	     AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [The posix library implements file allocation functions.]),
	     AC_MSG_WARN(POSIX implementation does not have file allocation functions.))
439

440
# Check for PARMETIS.
441
have_parmetis="no"
442
443
444
AC_ARG_WITH([parmetis],
    [AS_HELP_STRING([--with-parmetis=PATH],
       [root directory where ParMETIS is installed @<:@yes/no@:>@]
445
446
    )],
    [],
447
448
449
450
451
452
453
454
455
456
    [with_parmetis="no"]
)

# Don't proceed with old --with-metis option.
used_metis="no"
AC_ARG_WITH([metis],
    [AS_HELP_STRING([--with-metis],
       [no longer supported, use --with-parmetis]
    )],
    [used_metis="yes"],
457
    [:]
458
)
459
460
461
462
463
if test "x$used_metis" != "xno"; then
   AC_MSG_ERROR([Using unsupported --with-metis option, use --with-parmetis])
fi

if test "x$with_parmetis" != "xno"; then
464
465

# Check if we have ParMETIS.
466
467
468
   if test "x$with_parmetis" != "xyes" -a "x$with_parmetis" != "x"; then
      PARMETIS_LIBS="-L$with_parmetis/lib -lparmetis"
      PARMETIS_INCS="-I$with_parmetis/include"
469
   else
470
471
      PARMETIS_LIBS="-lparmetis"
      PARMETIS_INCS=""
472
   fi
473
474
   AC_CHECK_LIB([parmetis],[ParMETIS_V3_RefineKway], [have_parmetis="yes"],
                [have_parmetis="no"], $PARMETIS_LIBS)
475
476
   if test "$have_parmetis" == "no"; then

477
478
# A build may use an external METIS library, check for that.

479
480
481
      if test "x$with_parmetis" != "xyes" -a "x$with_parmetis" != "x"; then
         PARMETIS_LIBS="-L$with_parmetis/lib -lparmetis -lmetis"
         PARMETIS_INCS="-I$with_parmetis/include"
482
      else
483
484
         PARMETIS_LIBS="-lparmetis -lmetis"
         PARMETIS_INCS=""
485
      fi
486
487
      AC_CHECK_LIB([parmetis],[ParMETIS_V3_RefineKway], [have_parmetis="yes"],
                   [have_parmetis="no"], $PARMETIS_LIBS)
488
489

   fi
490
491
   if test "$have_parmetis" == "yes"; then
      AC_DEFINE([HAVE_PARMETIS],1,[The ParMETIS library is present.])
492
493
   else
      AC_MSG_ERROR("Failed to find a ParMETIS library")
494
   fi
495
fi
496

497
498
499
AC_SUBST([PARMETIS_LIBS])
AC_SUBST([PARMETIS_INCS])
AM_CONDITIONAL([HAVEPARMETIS],[test -n "$PARMETIS_LIBS"])
500

501
502
503
504
505
506
507
508
# METIS fixed width integer printing can require this, so define. Only needed
# for some non C99 compilers, i.e. C++ pre C++11.
AH_VERBATIM([__STDC_FORMAT_MACROS],
            [/* Needed to get PRIxxx macros from stdint.h when not using C99 */
#ifndef __STDC_FORMAT_MACROS
#define __STDC_FORMAT_MACROS 1
#endif])

509
510
511
512
513
514
515
516
517
518
# Check for grackle. 
have_grackle="no"
AC_ARG_WITH([grackle],
    [AS_HELP_STRING([--with-grackle=PATH],
       [root directory where grackle is installed @<:@yes/no@:>@]
    )],
    [],
    [with_grackle="no"]
)
if test "x$with_grackle" != "xno"; then
lhausamm's avatar
lhausamm committed
519
   AC_PROG_FC
520
521
   AC_FC_LIBRARY_LDFLAGS
   if test "x$with_grackle" != "xyes" -a "x$with_grackle" != "x"; then
522
      GRACKLE_LIBS="-L$with_grackle/lib -lgrackle"
523
524
      GRACKLE_INCS="-I$with_grackle/include"
   else
525
      GRACKLE_LIBS="-lgrackle"
526
527
      GRACKLE_INCS=""
   fi
528

529
   have_grackle="yes"
530

531
532
   AC_CHECK_LIB(
      [grackle],
533
      [initialize_chemistry_data],
lhausamm's avatar
lhausamm committed
534
      [AC_DEFINE([HAVE_GRACKLE],1,[The GRACKLE library appears to be present.])
lhausamm's avatar
lhausamm committed
535
536
        AC_DEFINE([CONFIG_BFLOAT_8],1,[Use doubles in grackle])
      ],
537
      [AC_MSG_ERROR(Cannot find grackle library!)],
538
      [$GRACKLE_LIBS $GRACKLE_INCS $FCLIBS]
539
540
541
542
543
544
545
   )
fi
AC_SUBST([GRACKLE_LIBS])
AC_SUBST([GRACKLE_INCS])
AM_CONDITIONAL([HAVEGRACKLE],[test -n "$GRACKLE_LIBS"])


546
547
548
549
550
551
552
553
554
555
#  Check for tcmalloc a fast malloc that is part of the gperftools.
have_tcmalloc="no"
AC_ARG_WITH([tcmalloc],
   [AS_HELP_STRING([--with-tcmalloc],
      [use tcmalloc library or specify the directory with lib @<:@yes/no@:>@]
   )],
   [with_tcmalloc="$withval"],
   [with_tcmalloc="no"]
)
if test "x$with_tcmalloc" != "xno"; then
Peter W. Draper's avatar
Peter W. Draper committed
556
   if test "x$with_tcmalloc" != "xyes" -a "x$with_tcmalloc" != "x"; then
557
      tclibs="-L$with_tcmalloc -ltcmalloc"
558
   else
559
      tclibs="-ltcmalloc"
560
561
   fi
   AC_CHECK_LIB([tcmalloc],[tc_cfree],[have_tcmalloc="yes"],[have_tcmalloc="no"],
562
                $tclibs)
563
564
565

   #  Could just have the minimal version.
   if test "$have_tcmalloc" = "no"; then
Peter W. Draper's avatar
Peter W. Draper committed
566
      if test "x$with_tcmalloc" != "xyes" -a "x$with_tcmalloc" != "x"; then
567
         tclibs="-L$with_tcmalloc -ltcmalloc_minimal"
568
      else
569
         tclibs="-ltcmalloc_minimal"
570
571
      fi
      AC_CHECK_LIB([tcmalloc],[tc_cfree],[have_tcmalloc="yes"],[have_tcmalloc="no"],
572
                   $tclibs)
573
   fi
Pedro Gonnet's avatar
Pedro Gonnet committed
574

575
576
577
578
   if test "$have_tcmalloc" = "yes"; then
      TCMALLOC_LIBS="$tclibs"

      # These are recommended for GCC.
579
      if test "$ax_cv_c_compiler_vendor" = "gnu"; then
580
581
582
583
         CFLAGS="$CFLAGS -fno-builtin-malloc -fno-builtin-calloc -fno-builtin-realloc -fno-builtin-free"
      fi
   else
      TCMALLOC_LIBS=""
584
585
586
587
588
   fi
fi
AC_SUBST([TCMALLOC_LIBS])
AM_CONDITIONAL([HAVETCMALLOC],[test -n "$TCMALLOC_LIBS"])

589
#  Check for -lprofiler usually part of the gperftools along with tcmalloc.
590
591
592
593
594
595
596
597
598
have_profiler="no"
AC_ARG_WITH([profiler],
   [AS_HELP_STRING([--with-profiler],
      [use cpu profiler library or specify the directory with lib @<:@yes/no@:>@]
   )],
   [with_profiler="$withval"],
   [with_profiler="yes"]
)
if test "x$with_profiler" != "xno"; then
Peter W. Draper's avatar
Peter W. Draper committed
599
   if test "x$with_profiler" != "xyes" -a "x$with_profiler" != "x"; then
600
      proflibs="-L$with_profiler -lprofiler"
601
   else
602
      proflibs="-lprofiler"
603
604
   fi
   AC_CHECK_LIB([profiler],[ProfilerFlush],[have_profiler="yes"],[have_profiler="no"],
605
606
607
608
609
610
611
                $proflibs)

   if test "$have_profiler" = "yes"; then
      PROFILER_LIBS="$proflibs"
   else
      PROFILER_LIBS=""
   fi
612
613
614
fi
AC_SUBST([PROFILER_LIBS])
AM_CONDITIONAL([HAVEPROFILER],[test -n "$PROFILER_LIBS"])
Pedro Gonnet's avatar
Pedro Gonnet committed
615

Peter W. Draper's avatar
Peter W. Draper committed
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
#  Check for jemalloc another fast malloc that is good with contention.
have_jemalloc="no"
AC_ARG_WITH([jemalloc],
   [AS_HELP_STRING([--with-jemalloc],
      [use jemalloc library or specify the directory with lib @<:@yes/no@:>@]
   )],
   [with_jemalloc="$withval"],
   [with_jemalloc="no"]
)
if test "x$with_jemalloc" != "xno"; then
   if test "x$with_jemalloc" != "xyes" -a "x$with_jemalloc" != "x"; then
      jelibs="-L$with_jemalloc -ljemalloc"
   else
      jelibs="-ljemalloc"
   fi
   AC_CHECK_LIB([jemalloc],[malloc_usable_size],[have_jemalloc="yes"],[have_jemalloc="no"],
                $jelibs)

   if test "$have_jemalloc" = "yes"; then
      JEMALLOC_LIBS="$jelibs"
   else
      JEMALLOC_LIBS=""
   fi
fi
AC_SUBST([JEMALLOC_LIBS])
AM_CONDITIONAL([HAVEJEMALLOC],[test -n "$JEMALLOC_LIBS"])

#  Don't allow both tcmalloc and jemalloc.
if test "x$have_tcmalloc" != "xno" -a "x$have_jemalloc" != "xno"; then
   AC_MSG_ERROR([Cannot use tcmalloc at same time as jemalloc])
fi

648
# Check for HDF5. This is required.
649
AX_LIB_HDF5
650
651
652
653
if test "$with_hdf5" != "yes"; then
    AC_MSG_ERROR([Could not find a working HDF5 library])
fi

654
655
656
# We want to know if this HDF5 supports MPI and whether we should use it.
# The default is to use MPI support if it is available, i.e. this is
# a parallel HDF5.
657
658
have_parallel_hdf5="no"
if test "$with_hdf5" = "yes"; then
659
660
    AC_ARG_ENABLE([parallel-hdf5],
       [AS_HELP_STRING([--enable-parallel-hdf5],
661
         [Enable parallel HDF5 library MPI functions if available. @<:@yes/no@:>@]
662
663
664
665
666
667
668
       )],
       [enable_parallel_hdf5="$enableval"],
       [enable_parallel_hdf5="yes"]
    )

    if test "$enable_parallel_hdf5" = "yes"; then
        AC_MSG_CHECKING([for HDF5 parallel support])
669
670
671
672
673
674
675
676
# Check if the library is capable, the header should define H5_HAVE_PARALLEL.

        AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
        #include "hdf5.h"
        #ifndef H5_HAVE_PARALLEL
        # error macro not defined
        #endif
        ]])], [parallel="yes"], [parallel="no"])
677
678
679
680
681
        if test "$parallel" = "yes"; then
            have_parallel_hdf5="yes"
            AC_DEFINE([HAVE_PARALLEL_HDF5],1,[HDF5 library supports parallel access])
        fi
        AC_MSG_RESULT($parallel)
682
683
684
685
    fi
fi
AM_CONDITIONAL([HAVEPARALLELHDF5],[test "$have_parallel_hdf5" = "yes"])

686
687
688
689
# Check for floating-point execeptions
AC_CHECK_FUNC(feenableexcept, AC_DEFINE([HAVE_FE_ENABLE_EXCEPT],[1],
    [Defined if the floating-point exception can be enabled using non-standard GNU functions.]))

690
# Check for setaffinity.
691
AC_CHECK_FUNC(pthread_setaffinity_np, AC_DEFINE([HAVE_SETAFFINITY],[1],
Pedro Gonnet's avatar
Pedro Gonnet committed
692
    [Defined if pthread_setaffinity_np exists.]) )
693
694
AM_CONDITIONAL(HAVESETAFFINITY,
    [test "$ac_cv_func_pthread_setaffinity_np" = "yes"])
695

696
have_numa="no"
697
698
699
700
701
if test "$ac_cv_func_pthread_setaffinity_np" = "yes"; then
  # Check for libnuma.
  AC_CHECK_HEADER([numa.h])
  if test "$ac_cv_header_numa_h" = "yes"; then
    AC_CHECK_LIB([numa], [numa_available])
702
    have_numa="yes"
703
704
  fi
fi
Angus Lepper's avatar
Angus Lepper committed
705

706
707
708
709
710
711
712
713
714
715
716
# Check for FFTW
have_fftw3="no"
AC_CHECK_HEADER([fftw3.h])
if test "$ac_cv_header_fftw3_h" = "yes"; then
   AC_CHECK_LIB([fftw3],[fftw_malloc], [AC_DEFINE([HAVE_FFTW],
   [1],[Defined if FFTW 3.x exists.])] )
   FFTW_LIBS="-lfftw3"
   have_fftw3="yes"
fi
AC_SUBST([FFTW_LIBS])

Pedro Gonnet's avatar
Pedro Gonnet committed
717
# Check for Intel and PowerPC intrinsics header optionally used by vector.h.
718
AC_CHECK_HEADERS([immintrin.h])
Pedro Gonnet's avatar
Pedro Gonnet committed
719
AC_CHECK_HEADERS([altivec.h])
720

721
# Check for timing functions needed by cycle.h.
Pedro Gonnet's avatar
Pedro Gonnet committed
722
723
AC_HEADER_TIME
AC_CHECK_HEADERS([sys/time.h c_asm.h intrinsics.h mach/mach_time.h])
724
725
726
AC_CHECK_TYPE([hrtime_t],[AC_DEFINE(HAVE_HRTIME_T, 1, [Define to 1 if hrtime_t
is defined in <sys/time.h>])],,
[#if HAVE_SYS_TIME_H
Pedro Gonnet's avatar
Pedro Gonnet committed
727
728
729
730
731
#include <sys/time.h>
#endif])
AC_CHECK_FUNCS([gethrtime read_real_time time_base_to_time clock_gettime mach_absolute_time])
AC_MSG_CHECKING([for _rtc intrinsic])
rtc_ok=yes
732
733
AC_LINK_IFELSE([AC_LANG_PROGRAM(
[[#ifdef HAVE_INTRINSICS_H
Pedro Gonnet's avatar
Pedro Gonnet committed
734
#include <intrinsics.h>
735
#endif]],
736
737
[[_rtc()]])],
[AC_DEFINE(HAVE__RTC,1,[Define if you have the UNICOS _rtc() intrinsic.])],[rtc_ok=no])
Pedro Gonnet's avatar
Pedro Gonnet committed
738
739
AC_MSG_RESULT($rtc_ok)

740
# Add warning flags by default, if these can be used. Option =error adds
741
# -Werror to GCC, clang and Intel.  Note do this last as compiler tests may
742
# become errors, if that's an issue don't use CFLAGS for these, use an AC_SUBST().
743
744
AC_ARG_ENABLE([compiler-warnings],
   [AS_HELP_STRING([--enable-compiler-warnings],
745
     [Enable compile time warning flags, if compiler is known @<:@error/no/yes)@:>@]
746
747
   )],
   [enable_warn="$enableval"],
748
   [enable_warn="error"]
749
750
)
if test "$enable_warn" != "no"; then
751

752
    # AX_CFLAGS_WARN_ALL does not give good warning flags for the Intel compiler
753
    # We will do this by hand instead and only default to the macro for unknown compilers
754
755
    case "$ax_cv_c_compiler_vendor" in
          gnu | clang)
756
             CFLAGS="$CFLAGS -Wall -Wextra -Wno-unused-parameter -Wshadow"
757
          ;;
758
	  intel)
759
             CFLAGS="$CFLAGS -w2 -Wunused-variable -Wshadow"
760
          ;;
761
762
763
	  *)
	     AX_CFLAGS_WARN_ALL
	  ;;
764
    esac
765

766
    # Add a "choke on warning" flag if it exists
767
    if test "$enable_warn" = "error"; then
768
       case "$ax_cv_c_compiler_vendor" in
769
          intel | gnu | clang)
770
771
772
             CFLAGS="$CFLAGS -Werror"
          ;;
       esac
773
    fi
774
775
fi

776
777
778
779
780
# Various package configuration options.

# Hydro scheme.
AC_ARG_WITH([hydro],
   [AS_HELP_STRING([--with-hydro=<scheme>],
781
      [Hydro dynamics to use @<:@gadget2, minimal, hopkins, default, gizmo, shadowfax debug default: gadget2@:>@]
782
783
784
785
786
787
   )],
   [with_hydro="$withval"],
   [with_hydro="gadget2"]
)
case "$with_hydro" in
   gadget2)
788
      AC_DEFINE([GADGET2_SPH], [1], [Gadget-2 SPH])
789
   ;;
790
791
   minimal)
      AC_DEFINE([MINIMAL_SPH], [1], [Minimal SPH])
792
   ;;
793
   hopkins)
794
      AC_DEFINE([HOPKINS_PE_SPH], [1], [Pressure-Entropy SPH])
795
   ;;
796
797
   default)
      AC_DEFINE([DEFAULT_SPH], [1], [Default SPH])
798
   ;;
799
800
   gizmo)
      AC_DEFINE([GIZMO_SPH], [1], [GIZMO SPH])
801
   ;;
802
803
   shadowfax)
      AC_DEFINE([SHADOWFAX_SPH], [1], [Shadowfax SPH])
804
   ;;
805
806

   *)
807
      AC_MSG_ERROR([Unknown hydrodynamics scheme: $with_hydro])
808
809
810
   ;;
esac

811
812
813
# Check if debugging interactions is switched on.
AC_ARG_ENABLE([debug-interactions],
   [AS_HELP_STRING([--enable-debug-interactions],
814
     [Activate interaction debugging, logging a maximum of @<:@N@:>@ neighbours. Defaults to 256 if no value set.]
815
816
817
818
   )],
   [enable_debug_interactions="$enableval"],
   [enable_debug_interactions="no"]
)
819
if test "$enable_debug_interactions" != "no"; then
820
  if test "$with_hydro" = "gadget2"; then
821
822
823
824
825
826
827
828
      AC_DEFINE([DEBUG_INTERACTIONS_SPH],1,[Enable interaction debugging])
    if test "$enable_debug_interactions" == "yes"; then
      AC_DEFINE([MAX_NUM_OF_NEIGHBOURS],256,[The maximum number of particle neighbours to be logged])
      [enable_debug_interactions="yes (Logging up to 256 neighbours)"]
    else
      AC_DEFINE_UNQUOTED([MAX_NUM_OF_NEIGHBOURS], [$enableval] ,[The maximum number of particle neighbours to be logged])
      [enable_debug_interactions="yes (Logging up to $enableval neighbours)"]
    fi
829
  else
830
831
832
833
    [enable_debug_interactions="no (only available for gadget2 hydro scheme)"]
  fi
fi

834
835
836
837
838
839
840
841
842
843
844
# SPH Kernel function
AC_ARG_WITH([kernel],
   [AS_HELP_STRING([--with-kernel=<kernel>],
      [Kernel function to use @<:@cubic-spline, quartic-spline, quintic-spline, wendland-C2, wendland-C4, wendland-C6 default: cubic-spline@:>@]
   )],
   [with_kernel="$withval"],
   [with_kernel="cubic-spline"]
)
case "$with_kernel" in
   cubic-spline)
      AC_DEFINE([CUBIC_SPLINE_KERNEL], [1], [Cubic spline kernel])
845
   ;;
846
847
   quartic-spline)
      AC_DEFINE([QUARTIC_SPLINE_KERNEL], [1], [Quartic spline kernel])
848
   ;;
849
850
   quintic-spline)
      AC_DEFINE([QUINTIC_SPLINE_KERNEL], [1], [Quintic spline kernel])
851
   ;;
852
853
   wendland-C2)
      AC_DEFINE([WENDLAND_C2_KERNEL], [1], [Wendland-C2 kernel])
854
   ;;
855
856
   wendland-C4)
      AC_DEFINE([WENDLAND_C4_KERNEL], [1], [Wendland-C4 kernel])
857
   ;;
858
859
   wendland-C6)
      AC_DEFINE([WENDLAND_C6_KERNEL], [1], [Wendland-C6 kernel])
860
   ;;
861
862
863
864
865
   *)
      AC_MSG_ERROR([Unknown kernel function: $with_kernel])
   ;;
esac

866
867
#  Dimensionality of the hydro scheme.
AC_ARG_WITH([hydro-dimension],
868
869
   [AS_HELP_STRING([--with-hydro-dimension=<dim>],
      [dimensionality of problem @<:@3/2/1 default: 3@:>@]
870
871
872
873
874
875
   )],
   [with_dimension="$withval"],
   [with_dimension="3"]
)
case "$with_dimension" in
   1)
876
      AC_DEFINE([HYDRO_DIMENSION_1D], [1], [1D solver])
877
   ;;
878
   2)
879
      AC_DEFINE([HYDRO_DIMENSION_2D], [2], [2D solver])
880
   ;;
881
   3)
882
      AC_DEFINE([HYDRO_DIMENSION_3D], [3], [3D solver])
883
   ;;
884
885
886
887
888
   *)
      AC_MSG_ERROR([Dimensionality must be 1, 2 or 3])
   ;;
esac

889
890
891
892
893
894
895
896
897
898
899
#  Equation of state
AC_ARG_WITH([equation-of-state],
   [AS_HELP_STRING([--with-equation-of-state=<EoS>],
      [equation of state @<:@ideal-gas, isothermal-gas default: ideal-gas@:>@]
   )],
   [with_eos="$withval"],
   [with_eos="ideal-gas"]
)
case "$with_eos" in
   ideal-gas)
      AC_DEFINE([EOS_IDEAL_GAS], [1], [Ideal gas equation of state])
900
   ;;
901
902
   isothermal-gas)
      AC_DEFINE([EOS_ISOTHERMAL_GAS], [1], [Isothermal gas equation of state])
903
   ;;
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
   *)
      AC_MSG_ERROR([Unknown equation of state: $with_eos])
   ;;
esac

#  Adiabatic index
AC_ARG_WITH([adiabatic-index],
   [AS_HELP_STRING([--with-adiabatic-index=<gamma>],
      [adiabatic index @<:@5/3, 7/5, 4/3, 2 default: 5/3@:>@]
   )],
   [with_gamma="$withval"],
   [with_gamma="5/3"]
)
case "$with_gamma" in
   5/3)
      AC_DEFINE([HYDRO_GAMMA_5_3], [5./3.], [Adiabatic index is 5/3])
920
   ;;
921
922
   7/5)
      AC_DEFINE([HYDRO_GAMMA_7_5], [7./5.], [Adiabatic index is 7/5])
923
   ;;
924
925
   4/3)
      AC_DEFINE([HYDRO_GAMMA_4_3], [4./3.], [Adiabatic index is 4/3])
926
   ;;
927
928
   2)
      AC_DEFINE([HYDRO_GAMMA_2_1], [2.], [Adiabatic index is 2])
929
   ;;
930
931
932
933
934
   *)
      AC_MSG_ERROR([Unknown adiabatic index: $with_gamma])
   ;;
esac

935
936
937
938
939
940
941
942
943
944
945
#  Riemann solver
AC_ARG_WITH([riemann-solver],
   [AS_HELP_STRING([--with-riemann-solver=<solver>],
      [riemann solver (gizmo-sph only) @<:@none, exact, trrs, hllc, default: none@:>@]
   )],
   [with_riemann="$withval"],
   [with_riemann="none"]
)
case "$with_riemann" in
   none)
      AC_DEFINE([RIEMANN_SOLVER_NONE], [1], [No Riemann solver])
946
   ;;
947
948
   exact)
      AC_DEFINE([RIEMANN_SOLVER_EXACT], [1], [Exact Riemann solver])
949
   ;;
950
951
   trrs)
      AC_DEFINE([RIEMANN_SOLVER_TRRS], [1], [Two Rarefaction Riemann Solver])
952
   ;;
953
954
   hllc)
      AC_DEFINE([RIEMANN_SOLVER_HLLC], [1], [Harten-Lax-van Leer-Contact Riemann solver])
955
   ;;
956
957
958
959
960
   *)
      AC_MSG_ERROR([Unknown Riemann solver: $with_riemann])
   ;;
esac

961
962
963
964
965
966
967
968
969
970
971
#  Cooling function
AC_ARG_WITH([cooling],
   [AS_HELP_STRING([--with-cooling=<function>],
      [cooling function @<:@none, const-du, const-lambda, grackle default: none@:>@]
   )],
   [with_cooling="$withval"],
   [with_cooling="none"]
)
case "$with_cooling" in
   none)
      AC_DEFINE([COOLING_NONE], [1], [No cooling function])
972
   ;;
973
974
   const-du)
      AC_DEFINE([COOLING_CONST_DU], [1], [Const du/dt cooling function])
975
   ;;
976
977
   const-lambda)
      AC_DEFINE([COOLING_CONST_LAMBDA], [1], [Const Lambda cooling function])
978
   ;;
979
980
   grackle)
      AC_DEFINE([COOLING_GRACKLE], [1], [Cooling via the grackle library])
981
   ;;
982
983
   EAGLE)
      AC_DEFINE([COOLING_EAGLE], [1], [Cooling following the EAGLE model])
984
   ;;
985
986
987
988
989
   *)
      AC_MSG_ERROR([Unknown cooling function: $with_cooling])
   ;;
esac

lhausamm's avatar
lhausamm committed
990
991
992
#  chemistry function
AC_ARG_WITH([chemistry],
   [AS_HELP_STRING([--with-chemistry=<function>],
993
      [chemistry function @<:@none, gear, EAGLE default: none@:>@]
lhausamm's avatar
lhausamm committed
994
995
996
997
998
999
1000
   )],
   [with_chemistry="$withval"],
   [with_chemistry="none"]
)
case "$with_chemistry" in
   none)
      AC_DEFINE([CHEMISTRY_NONE], [1], [No chemistry function])
1001
   ;;
1002
1003
   gear)
      AC_DEFINE([CHEMISTRY_GEAR], [1], [Chemistry taken from the GEAR model])
1004
   ;;
1005
1006
   EAGLE)
      AC_DEFINE([CHEMISTRY_EAGLE], [1], [Chemistry taken from the EAGLE model])
1007
   ;;
lhausamm's avatar
lhausamm committed
1008
1009
1010
1011
1012
   *)
      AC_MSG_ERROR([Unknown chemistry function: $with_chemistry])
   ;;
esac

1013
1014
1015
#  External potential
AC_ARG_WITH([ext-potential],
   [AS_HELP_STRING([--with-ext-potential=<pot>],
1016
      [external potential @<:@none, point-mass, isothermal, softened-isothermal, disc-patch, sine-wave default: none@:>@]
1017
1018
1019
1020
1021
1022
1023
   )],
   [with_potential="$withval"],
   [with_potential="none"]
)
case "$with_potential" in
   none)
      AC_DEFINE([EXTERNAL_POTENTIAL_NONE], [1], [No external potential])
1024
   ;;
1025
1026
   point-mass)
      AC_DEFINE([EXTERNAL_POTENTIAL_POINTMASS], [1], [Point-mass external potential])
1027
   ;;
1028
1029
   isothermal)
      AC_DEFINE([EXTERNAL_POTENTIAL_ISOTHERMAL], [1], [Isothermal external potential])
1030
   ;;
1031
1032
   disc-patch)
      AC_DEFINE([EXTERNAL_POTENTIAL_DISC_PATCH], [1], [Disc-patch external potential])
1033
   ;;
1034
1035
   sine-wave)
      AC_DEFINE([EXTERNAL_POTENTIAL_SINE_WAVE], [1], [Sine wave external potential in 1D])
1036
   ;;
1037
1038
1039
1040
   *)
      AC_MSG_ERROR([Unknown external potential: $with_potential])
   ;;
esac
1041

1042
1043
1044
#  Gravity multipole order
AC_ARG_WITH([multipole-order],
   [AS_HELP_STRING([--with-multipole-order=<order>],
1045
      [order of the multipole and gravitational field expansion @<:@ default: 5@:>@]
1046
1047
   )],
   [with_multipole_order="$withval"],
1048
   [with_multipole_order="5"]
1049
1050
)
AC_DEFINE_UNQUOTED([SELF_GRAVITY_MULTIPOLE_ORDER], [$with_multipole_order], [Multipole order])
1051
1052


1053
1054
1055
# Check for git, needed for revision stamps.
AC_PATH_PROG([GIT_CMD], [git])
AC_SUBST([GIT_CMD])
1056

1057
# Make the documentation. Add conditional to handle disable option.
1058
DX_INIT_DOXYGEN(libswift,doc/Doxyfile,doc/)
1059
AM_CONDITIONAL([HAVE_DOXYGEN], [test "$ac_cv_path_ac_pt_DX_DOXYGEN" != ""])
Pedro Gonnet's avatar
Pedro Gonnet committed
1060

1061
# Handle .in files.
1062
AC_CONFIG_FILES([Makefile src/Makefile examples/Makefile doc/Makefile doc/Doxyfile tests/Makefile])
1063
AC_CONFIG_FILES([tests/testReading.sh], [chmod +x tests/testReading.sh])
1064
AC_CONFIG_FILES([tests/testActivePair.sh], [chmod +x tests/testActivePair.sh])
1065
1066
AC_CONFIG_FILES([tests/test27cells.sh], [chmod +x tests/test27cells.sh])
AC_CONFIG_FILES([tests/test27cellsPerturbed.sh], [chmod +x tests/test27cellsPerturbed.sh])
1067
AC_CONFIG_FILES([tests/test125cells.sh], [chmod +x tests/test125cells.sh])
1068
AC_CONFIG_FILES([tests/test125cellsPerturbed.sh], [chmod +x tests/test125cellsPerturbed.sh])
1069
AC_CONFIG_FILES([tests/testPeriodicBC.sh], [chmod +x tests/testPeriodicBC.sh])
1070
AC_CONFIG_FILES([tests/testPeriodicBCPerturbed.sh], [chmod +x tests/testPeriodicBCPerturbed.sh])
1071
AC_CONFIG_FILES([tests/testInteractions.sh], [chmod +x tests/testInteractions.sh])
1072
AC_CONFIG_FILES([tests/testParser.sh], [chmod +x tests/testParser.sh])
Pedro Gonnet's avatar
Pedro Gonnet committed
1073

1074
1075
1076
# Save the compilation options
AC_DEFINE_UNQUOTED([SWIFT_CONFIG_FLAGS],["$swift_config_flags"],[Flags passed to configure])

1077
1078
1079
1080
1081
1082
# Make sure the latest git revision string gets included
touch src/version.c

# Generate output.
AC_OUTPUT

1083
# Report general configuration.
1084
AC_MSG_RESULT([
1085
 ------- Summary --------
1086
1087
1088

   $PACKAGE_NAME v.$PACKAGE_VERSION

1089
1090
1091
1092
1093
1094
1095
   Compiler         : $CC
    - vendor        : $ax_cv_c_compiler_vendor
    - version       : $ax_cv_c_compiler_version
    - flags         : $CFLAGS
   MPI enabled      : $enable_mpi
   HDF5 enabled     : $with_hdf5
    - parallel      : $have_parallel_hdf5
1096
   ParMETIS enabled : $have_parmetis
1097
   FFTW3 enabled    : $have_fftw3
1098
   GSL enabled      : $have_gsl
1099
   libNUMA enabled  : $have_numa
1100
   GRACKLE enabled  : $have_grackle
1101
1102
1103
1104
   Using tcmalloc   : $have_tcmalloc
   Using jemalloc   : $have_jemalloc
   CPU profiler     : $have_profiler
   Pthread barriers : $have_pthread_barrier
1105
1106
1107
1108
1109
1110

   Hydro scheme       : $with_hydro
   Dimensionality     : $with_dimension
   Kernel function    : $with_kernel
   Equation of state  : $with_eos
   Adiabatic index    : $with_gamma
1111
   Riemann solver     : $with_riemann
1112
   Cooling function   : $with_cooling
lhausamm's avatar
lhausamm committed
1113
   Chemistry          : $with_chemistry
1114

1115
1116
1117
1118
   External potential  : $with_potential
   Multipole order     : $with_multipole_order
   No gravity below ID : $no_gravity_below_id

1119
1120
1121
1122
1123
1124
1125
   Individual timers     : $enable_timers
   Task debugging        : $enable_task_debugging
   Threadpool debugging  : $enable_threadpool_debugging
   Debugging checks      : $enable_debugging_checks
   Interaction debugging : $enable_debug_interactions
   Naive interactions    : $enable_naive_interactions
   Gravity checks        : $gravity_force_checks
1126
1127

 ------------------------])